***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 28, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD25N06A-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6			level = 3
+  vto = 2.45		       kp = 21.75)
.model  dds   d( 
+   is = 8.965e-12	  n = 1.137			   rs = 3.291e-3
+   eg = 1.11	     trs1 = 1.000e-3)
.model  dbody d( 
+   is = 8.965e-12	  n = 1.137			   rs = 3.291e-3
+  cjo = 1.773e-10	  m = 5.815e-1		   vj = 6.134e-1	
+   bv = 66	      ibv = 250e-6		 tbv1 = 9.532e-4			tt = 25n
+ trs1 = 6e-4)          
.model  inter  nmos( 
+  vto = 0			 kp = 10			level = 1)
.model  dgd    d(
+  cjo = 2.836-10		  m = 4.694e-1		   vj = 3.005e-1)
.param 
+  cgs = 1.433e-09	cgd = 2.82e-10
+   rd = 9.031e-3	      ra  = 9.031e-3		  trd = 2.217e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   ic = 0
egv	  2t  3   table   {v(1t, S)} 
+((0   , 0   ),
+ (0.5 , 0.5 ), 
+ (1   , 1   ),
+ (1.5 , 1.5 ),
+ (2   , 2),
+ (3   , 3), 
+ (3.4, 3.5),
+ (3.5, 3.6),
+ (3.7, 3.8),
+ (4, 5.2),
+ (4.5 , 6.2),
+ (5   , 6.6),
+ (6   , 7),
+ (8   , 8),
+ (10  , 9),   
+ (20  , 20),
+ (22  , 22))
egt	  1  2t   value = {7.287e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4   1t  2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$